Gecko [ www.jobworksschool.com ]

Name	Size	Permission	Date
_bootctl	3.04 KB	-rw-r--r--	2024-02-27 17:26
_busctl	9.43 KB	-rw-r--r--	2024-02-27 17:26
_curl	15.84 KB	-rw-r--r--	2026-07-06 17:02
_hostnamectl	2.73 KB	-rw-r--r--	2024-02-27 17:26
_journalctl	7.03 KB	-rw-r--r--	2024-02-27 17:26
_kernel-install	779 B	-rw-r--r--	2024-02-27 17:26
_localectl	3.69 KB	-rw-r--r--	2024-02-27 17:26
_loginctl	6.25 KB	-rw-r--r--	2024-02-27 17:26
_networkctl	2.37 KB	-rw-r--r--	2024-02-27 17:26
_resolvectl	3.71 KB	-rw-r--r--	2024-02-27 17:26
_sd_hosts_or_user_at_host	128 B	-rw-r--r--	2024-02-27 17:26
_sd_outputmodes	318 B	-rw-r--r--	2024-02-27 17:26
_sd_unit_files	263 B	-rw-r--r--	2024-02-27 17:26
_snap	1.78 KB	-rw-r--r--	2026-05-28 18:00
_systemctl	20.83 KB	-rw-r--r--	2026-06-05 15:36
_systemd	3.76 KB	-rw-r--r--	2024-02-27 17:26
_systemd-analyze	5.5 KB	-rw-r--r--	2024-02-27 17:26
_systemd-delta	633 B	-rw-r--r--	2024-02-27 17:26
_systemd-inhibit	1.15 KB	-rw-r--r--	2024-02-27 17:26
_systemd-path	330 B	-rw-r--r--	2024-02-27 17:26
_systemd-run	4.25 KB	-rw-r--r--	2024-02-27 17:26
_systemd-tmpfiles	744 B	-rw-r--r--	2024-02-27 17:26
_timedatectl	2.12 KB	-rw-r--r--	2024-02-27 17:26
_udevadm	8.51 KB	-rw-r--r--	2024-02-27 17:26

Rename

#compdef networkctl
# SPDX-License-Identifier: LGPL-2.1-or-later

(( $+functions[_networkctl_commands] )) ||
    _networkctl_commands() {
        local -a _networkctl_cmds
        _networkctl_cmds=(
            'list:List existing links'
            'status:Show information about the specified links'
            'lldp:Show Link Layer Discovery Protocol status'
            'label:Show address labels'
            'delete:Delete virtual netdevs'
            'edit:Edit network configurations'
            'cat:Cat network configurations'
            'up:Bring devices up'
            'down:Bring devices down'
            'renew:Renew dynamic configurations'
            'forcerenew:Trigger DHCP reconfiguration of all connected clients'
            'reconfigure:Reconfigure interfaces'
            'reload:Reload .network and .netdev files'
        )
        if (( CURRENT == 1 )); then
            _describe -t commands 'networkctl command' _networkctl_cmds
        else
            local curcontext="$curcontext"
            local -a _links
            cmd="${${_networkctl_cmds[(r)$words[1]:*]%%:*}}"
            case $cmd in
                (list|status|up|down|cat|edit|lldp|delete|renew|forcerenew|reconfigure)
                    for link in ${(f)"$(_call_program links networkctl list --no-legend)"}; do _links+=($link[(w)2]:$link); done
                    if [[ -n "$_links" ]]; then
                        _describe -t links 'links' _links _links $( [[ $cmd == (edit|cat) ]] && print -- -P@ )
                    else
                        _message "no links"
                    fi
                    ;;
                *)
                    _message "no more options"
                    ;;
            esac
        fi
    }

(( $+functions[_networkctl_get_json] )) || _networkctl_get_json()
{
    local -a _json_forms
    _json_forms=( $(networkctl --json=help 2>/dev/null) )
    _values 'format' $_json_forms
}

_arguments \
    {-a,--all}'[Show all links with status]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-legend[Do not print the column headers]' \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--drop-in=[Use the given drop-in file name]' \
    '--no-reload[Do not reload the network manager state when editing]' \
    '--json[Shows output formatted as JSON]:format:_networkctl_get_json' \
    '*::networkctl commands:_networkctl_commands'